SimoneVB.it

Vai ai contenuti

Il primo script

Prodotti > WebPdfconverterLib



Vediamo un primo esempio di WebPdfConverterLib 1.2.0.
Qui di seguito un semplice listato ASP per realizzare l'applicazione descritta nell'introduzione.

Dim objConverter, objPDF, objTIFF
Dim sReturnMessage

' Istanzia classe WebPDFConverterLib.Converter
set objConverter = Server.CreateObject("WebPDFConverterLib.Converter")

' Accede ad account e verifica licenza
if not objConverter.CheckLicenceKey("your@email.it", "yourpassword", "your licence code here", sReturnMessage) then

    ' Errore
    Response.Write "Errore: " & sReturnMessage
    set objConverter = nothing
    Response.End
end if

' Importa copertina, documento Word e foglio Excel in quest'ordine
Call objConverter.AddPicture(Server.MapPath("relazione-agosto2009/copertina.jpg"))
Call objConverter.AddWord(Server.MapPath("relazione-agosto2009/relazione.doc"))
Call objConverter.AddExcel(Server.MapPath("relazione-agosto2009/statistiche.xls"))


' Crea un output per PDF e uno per TIFF
set objPDF = objConverter.NewOutPut("pdf")
set objTIFF = objConverter.NewOutPut("tiff")

' Imposta la proprietà del PDF
with objPDF
    .LanguageLevel = 2

    .Title = "Relazione agosto 2009"
    .Author = "Mario Rossi"
    .Generator = "GestionaleWeb"

    .OwnerPassword = "admin"     ' assegna password per modifica PDF
    .UserPassword = "password"     ' assegna password per visualizzazione PDF

    .OptimizedForPrinters = false ' Ottimizza il documento per schermi
end with

Call objConverter.Resolution.setResolution(130) ' Imposta risoluzione immagini a 130dpi
Call objConverter.setPaperSize("A4") ' Imposta formato pagina

' Esporta l'insieme dei documenti in un file PDF e un file TIFF
Call objConverter.Convert(objPDF, Server.MapPath("relazione-agosto2009/relazione.pdf"))
Call objConverter.Convert(objTIFF, Server.MapPath("relazione-agosto2009/relazione.tiff"))

set objPDF = nothing
set objTIFF = nothing

set objConverter = nothing

Questo primo esempio mostra con quanta semplicità possiamo ottenere il risultato descritto nell'introduzione:
l'unione di tre documenti esportati poi nei due formati PDF e TIFF.

La funzione CheckLicenceKey vi permette verificare la chiave della vostra licenza prima di potere
usufruire a pieno di tutte le funzionalità di WebPdfConverterLib.

Con le funzioni AddPicture, AddWord e AddExcel abbiamo visto come importare immagini, documenti
di Word e Fogli Excel.

La funzione NewOutPut ci ha permesso di istanziare due oggetti per gestire l'esportazione di altrettanti
diversi tipi di documeti: appunto PDF e TIFF.
Volendo, avremmo potuto creare oggetti output appositi per esportare in BMP, JPEG, PNG, TIFF o anche EPS, ma
vedremo più avanti in questa guida come fare.

Intervenendo sulle proprietà dell'oggetto outputPDF (objPDF), abbiamo potuto impostare diverse proprietà
del nostro documento PDF. Come descritto dai commenti nel codice, abbiamo impostato la versione del PDF, il titolo,
il nome dell'autore e il nome dell'applicazione generator, nonchè la password per la lettura e quella per la modifica
del PDF. Infine abbiamo ottimizzato per gli schermi il nostro documento PDF.

Con la funzione Converter.Resolution.setResolution abbiamo impostato a 130 dpi la risoluzione di tutte
le immagini contenute in tutti i documenti importati

Richiamando la funzione setPaperSize abbiamo impostato le dimensioni di pagina del documento esportato uguali
a quelle di un foglio A4.

Infine, con la funzione Convert abbiamo visto com'è possibile esportare l'insieme dei
documenti importati, in tutti i formati per cui abbiamo istanziato uno specifico oggetto output.

Tornando sulla funzione CheckLicenceKey: a questa funzione vanno passati nell'ordine:
l'indirizzo email specificato al momento dell'acquisto della licenza, la password e la chiave di licenza
che vi verranno assegnate automaticamente e inviate per email al momento dell'acquisto.

Ma vediamo come sia possibile cominciare a integrare WebPdfConverterLib nel vostro sito web, subito dopo averlo installato,
senza dovere necessariamente acquistare una licenza: Utilizzando l'account 'demo'.


Home Page | Prodotti | Referenze | Progetti | Contatti | Mappa del sito

Torna ai contenuti | Torna al menu